|
一,、無組件上傳的原理
我還是一點一點用一個實例來說明的吧,，客戶端HTML如下。要瀏覽上傳附件,，我們通過<input type="file">元素,，但是一定要注意必須設(shè)置form的enctype屬性為"multipart/form-data"：
<form method="post" action="upload.asp" enctype="multipart/form-data">
<label>
<input type="file" name="file1" />
</label>
<br />
<input type="text" name="filename" value="default filename"/>
<br />
<input type="submit" value="Submit"/>
<input type="reset" value="Reset"/>
</form>
在后臺asp程序中,，以前獲取表單提交的ASCII 數(shù)據(jù)，非常的容易,。但是如果需要獲取上傳的文件,，就必須使用Request對象的BinaryRead方法來讀取。BinaryRead方法是對當(dāng)前輸入流進行指定字節(jié)數(shù)的二進制讀取,，有點需要注意的是,，一旦使用BinaryRead 方法后，再也不能使用Request.Form 或 Request.QueryString 集合了,。結(jié)合Request對象的TotalBytes屬性,，可以將所有表單提交的數(shù)據(jù)全部變成二進制，不過這些數(shù)據(jù)都是經(jīng)過編碼的,。首先讓我們來看看這些數(shù)據(jù)是如何編碼的,，有無什么規(guī)律可循，編段代碼,，在代碼中我們將BinaryRead讀取的二進制轉(zhuǎn)化為文本,，輸出出來，在后臺的upload.asp中（注意該示例不要上傳大文件,，否則可能會造成瀏覽器死掉）：
<%
Dim biData, PostData
Size = Request.TotalBytes
biData = Request.BinaryRead(Size)
PostData = BinaryToString(biData,Size)
Response.Write "<PRe>" & PostData & "</pre>" '使用pre,，原樣輸出格式
' 借助RecordSet將二進制流轉(zhuǎn)化成文本
Function BinaryToString(biData,Size)
Const adLongVarChar = 201
Set RS = CreateObject("ADODB.Recordset")
RS.Fields.Append "mBinary", adLongVarChar, Size
RS.Open
RS.AddNew
RS("mBinary").AppendChunk(biData)
RS.Update
BinaryToString = RS("mBinary").Value
RS.Close
End Function
%>
簡單起見，上傳一個最簡單的文本文件(G:\homepage.txt,，內(nèi)容為"寶玉：http://www./")來試驗一下,，文本框filename中保留默認值"default filename"，提交看看輸出結(jié)果：
-----------------------------7d429871607fe
Content-Disposition: form-data; name="file1"; filename="G:\homepage.txt"
Content-Type: text/plain
寶玉：http://www./
-----------------------------7d429871607fe
Content-Disposition: form-data; name="filename"
default filename
-----------------------------7d429871607fe--
可以看出來對于表單中的項目,，是用過"-----------------------------7d429871607fe"這樣的邊界來分隔成一塊一塊的,，每一塊的開始都有一些描述信息，例如：Content-Disposition: form-data; name="filename",，在描述信息中,，通過name="filename"可以知道表單項的name。如果有filename="G:\homepage.txt"這樣的內(nèi)容,，說明是一個上傳的文件,，如果是一個上傳的文件，那么描述信息會多一行Content-Type: text/plain來描述文件的Content-Type,。描述信息和主體信息之間是通過換行來分隔的,。
嗯，基本上清晰了,，根據(jù)這個規(guī)律我們就知道該怎么來分離數(shù)據(jù),，再對分離的數(shù)據(jù)進行處理了，不過差點忽略一個問題,，就是邊界值(上例中的"-----------------------------7d429871607fe")是怎么知道的,？每次上傳這個邊界值是不一樣的,，還好還好asp中可以通過Request.ServerVariables( "HTTP_CONTENT_TYPE")來獲之，例如上例中HTTP_CONTENT_TYPE內(nèi)容為："multipart/form-data; boundary=---------------------------7d429871607fe",，有了這個,，我們不僅可以判斷客戶端的form中有無使用enctype="multipart/form-data"(如果沒有使用，那么下面就沒必要執(zhí)行啦),，還可以獲取邊界值boundary=---------------------------7d429871607fe,。（注意：這里獲取的邊界值比上面的邊界值開頭要少"--"，最好補充上,。）
至于如何分析數(shù)據(jù)的過程我就不多贅述了,，無非就是借助InStr,Mid等這樣的函數(shù)來分離出來我們想要的數(shù)據(jù)。
二,、分塊上傳,，記錄進度
要實時反映進度條，實質(zhì)就是要實時知道當(dāng)前服務(wù)器獲取了多少數(shù)據(jù),？再回想一下我們實現(xiàn)上傳的過程,，我們是通過Request.BinaryRead(Request.TotalBytes)來實現(xiàn)的，在Request的過程中我們無法得知當(dāng)前服務(wù)器獲取了多少數(shù)據(jù),。所以只能通過變通的方法了，如果我們可以將獲取的數(shù)據(jù)分成一塊一塊的,，然后根據(jù)已經(jīng)上傳的塊數(shù)我們就可以算出來當(dāng)前上傳了多大了,！也就是說，如果我1K為1塊,，那么上傳1MB的輸入流就分成1024塊來獲取,，例如我當(dāng)前已經(jīng)獲取了100塊，那么就表明當(dāng)前上傳了100K,。當(dāng)我提出分塊的時候很多人覺得不可思議,，因為他們都忽略BinaryRead方法不僅是可以讀取指定大小，而且可以連續(xù)讀取的,。
寫個例子來驗證一下分塊讀取的完整性,，在剛才的例子基礎(chǔ)上（注意該示例不要上傳大文件，否則可能會造成瀏覽器死掉）：
<%
Dim biData, PostData, TotalBytes, ChunkBytes
ChunkBytes = 1 * 1024 ' 分塊大小為1K
TotalBytes = Request.TotalBytes ' 總大小
PostData = "" ' 轉(zhuǎn)化為文本類型后的數(shù)據(jù)
ReadedBytes = 0 ' 初始化為0
' 分塊讀取
Do While ReadedBytes < TotalBytes
biData = Request.BinaryRead(ChunkBytes) ' 當(dāng)前塊
PostData = PostData & BinaryToString(biData,ChunkBytes) ' 將當(dāng)前塊轉(zhuǎn)化為文本并拼接
ReadedBytes = ReadedBytes + ChunkBytes ' 記錄已讀大小
If ReadedBytes > TotalBytes Then ReadedBytes = TotalBytes
Loop
Response.Write "<pre>" & PostData & "</pre>" ' 使用pre,，原樣輸出格式
' 將二進制流轉(zhuǎn)化成文本
Function BinaryToString(biData,Size)
Const adLongVarChar = 201
Set RS = CreateObject("ADODB.Recordset")
RS.Fields.Append "mBinary", adLongVarChar, Size
RS.Open
RS.AddNew
RS("mBinary").AppendChunk(biData)
RS.Update
BinaryToString = RS("mBinary").Value
RS.Close
End Function
%>
試驗一下上傳剛才的文本文件,，輸出結(jié)果證明這樣分塊讀取的內(nèi)容是完整的，并且在While循環(huán)中,，我們可以在每次循環(huán)時將當(dāng)前狀態(tài)記錄到application中,，然后我們就可以通過訪問該Application動態(tài)獲取上傳進度條。
另：上例中是通過字符串拼接的,，如果是要拼接二進制數(shù)據(jù),，可以通過ADODB.Stream對象的Write方法,，示例代碼如下：
Set bSourceData = createobject("ADODB.Stream")
bSourceData.Open
bSourceData.Type = 1 'Binary
Do While ReadedBytes < TotalBytes
biData = Request.BinaryRead(ChunkBytes)
bSourceData.Write biData ' 直接使用write方法將當(dāng)前文件流寫入bSourceData中
ReadedBytes = ReadedBytes + ChunkBytes
If ReadedBytes > TotalBytes Then ReadedBytes = TotalBytes
Application("ReadedBytes") = ReadedBytes
Loop
三、保存上傳的文件
通過Request.BinaryRead獲取提交數(shù)據(jù),，分離出上傳文件后,，根據(jù)數(shù)據(jù)類型的不同，保存方式也不同：
對于二進制數(shù)據(jù),，可以直接通過ADODB.Stream對象的SaveToFile方法,，將二進制流保存成為文件。
對于文本數(shù)據(jù),，可以通過TextStream對象的Write方法,，將文本數(shù)據(jù)保存到文件中。
對于文本數(shù)據(jù)和二進制數(shù)據(jù),，是可以方便的相互轉(zhuǎn)換的,，對于上傳小文件來說，兩者基本上沒什么差別,。但是兩種方式保存時還是有一些差別的,，對于ADODB.Stream對象，必須將所有數(shù)據(jù)全部裝載完才可以保存成文件,，所以使用這種方式如果上傳大文件將很占用內(nèi)存,，而對于TextStream對象，可以在文件創(chuàng)建好后,，一次Write一部分,，分多次Write，這樣的好處是不會占用服務(wù)器內(nèi)存空間,，結(jié)合上面分析的分塊獲取數(shù)據(jù)原理,，我們可以每獲取一塊上傳數(shù)據(jù)就將之Write到文件中。我曾做過試驗,，同樣本機上傳一個200多MB的文件,，使用第一種方式內(nèi)存一直在漲，到最后直接提示計算機虛擬內(nèi)存不足,，最可恨是即使進度條表示文件已經(jīng)上傳完,，但是最終文件還是沒有保存上。而使用后一種方法,，上傳過程中內(nèi)存基本上無什么變化,。
四、未解決的難題
我在博客園上看到Bestcomy描述他的asp.net上傳組件是可以和Sever.SetTimeOut無關(guān)的,，而在Asp中我是沒能做到,，對于上傳大文件，就只有將Server.SetTimeOut設(shè)置為一個很大的值才可以,。不知道有沒有比較好的解決方法,。
如果我們在保存文件時,，使用TextStream對象的Write方法，那么如果用戶上傳時中斷了文件傳輸,，已經(jīng)上傳的那部分文件還是在的,，如果可以斷點續(xù)傳就好了。關(guān)鍵問題是Request.BinaryRead方法雖然可以分塊讀取,，但是卻不能跳過某一段讀?。?/P>
五,、結(jié)束語
原理基本上是說清楚了,，但是實際代碼要比這復(fù)雜的多，要考慮很多問題,，最麻煩在分析數(shù)據(jù)那部分,，對于每一塊獲取的數(shù)據(jù),，要分析是不是屬于描述信息，是表單項目還是上傳的文件,，文件是否已經(jīng)上傳結(jié)束……
相信根據(jù)上面的描述,，您也可以開發(fā)出您自己功能強大的無組件上傳組件,。我想更多的人關(guān)心的只是代碼,，而不會自己動手去寫的,，也許沒有時間，也許水平還不夠,，更多的只是已經(jīng)成為了一種習(xí)慣……我在CSDN上見過太多技術(shù)八股文——一段說明,，然后全是代碼。授人以魚不若授人以漁,，給你一個代碼,，也許你并不會去思考為什么,，直接拿去用,，當(dāng)下次碰到類似的問題的時候，還是不知道為什么,，希望此文能讓更多人學(xué)到點什么，最重要是“悟”到點什么,！
|
