Function FindEmptyRow(ws As Worksheet) As Long
Dim lngReturn As Long
lngReturn = ws.Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).Row
FindEmptyRow = lngReturn
End Function

Private m_lngID      As Long
Private m_strName    As String
Private m_strSchool  As String
Private m_blnAbility As Boolean
Private m_blnObey    As Boolean
Private m_xlWksht    As Worksheet
Private m_oXL        As cExcelUtils

Property Get ID() As Long
ID = m_lngID
End Property
 
Property Get Name() As String
Name = m_strName
End Property
 
Property Let Name(newName As String)
m_strName = newName
End Property
 
Property Get School() As String
School = m_strSchool
End Property
 
Property Let School(newSchool As String)
m_strSchool = newSchool
End Property
 
Property Get Ability() As Boolean
Ability = m_blnAbility
End Property
 
Property Let Ability(newAbility As Boolean)
m_blnAbility = newAbility
End Property
 
Property Get Obey() As Boolean
Obey = m_blnObey
End Property
 
Property Let Obey(newObey As Boolean)
m_blnObey = newObey
End Property
 
Property Get DBWorkSheet() As Worksheet
Set DBWorkSheet = m_xlWksht
End Property
 
Property Set DBWorkSheet(newSheet As Worksheet)
Set m_xlWksht = newSheet
End Property

Public Function GetNextID() As Long
Dim lngReturn As Long
lngReturn = m_xlWksht.Cells(Rows.Count, 1).End(xlUp).Value + 1
m_lngID = lngReturn '設(shè)置ID屬性
    GetNextID = lngReturn
End Function

Private Sub Class_Initialize()
Set m_oXL = New cExcelUtils
End Sub
 
Private Sub Class_Terminate()
Set m_oXL = Nothing
End Sub

Public Function ValidateData() As Boolean
Dim blnReturn As Boolean
If (Len(Me.Name & "") * Len(Me.School & "")) = 0 Then
blnReturn = False
Else
blnReturn = True
End If
ValidateData = blnReturn
End Function

Public Function Save() As Boolean
Dim lngNewRowNum As Long
Dim blnReturn As Boolean
 
If m_xlWksht Is Nothing Then
blnReturn = False
GoTo Exit_Function
End If
 
lngNewRowNum = m_oXL.FindEmptyRow(m_xlWksht)
 
With m_xlWksht
.Cells(lngNewRowNum, 1).Value = Me.ID
.Cells(lngNewRowNum, 2).Value = Me.Name
.Cells(lngNewRowNum, 3).Value = Me.School
.Cells(lngNewRowNum, 4).Value = Me.Ability
.Cells(lngNewRowNum, 5).Value = Me.Obey
End With
 
If Err.Number = 0 Then
blnReturn = True
End If
 
Exit_Function:
Save = blnReturn
Exit Function
End Function

Private m_oEmployeeInfo As cEmployeeInfo
Private m_blnSaved As Boolean

Private Sub UserForm_Initialize()
Set m_oEmployeeInfo = New cEmployeeInfo
Set m_oEmployeeInfo.DBWorkSheet = Sheets("入職員工信息")
m_oEmployeeInfo.GetNextID
lblID.Caption = m_oEmployeeInfo.ID
m_blnSaved = False
ClearForm
End Sub
 
Private Sub UserForm_Terminate()
Set m_oEmployeeInfo = Nothing
End Sub

Private Sub ClearForm()
Me.txtName.Value = ""
Me.txtSchool.Value = ""
Me.chkAbility.Value = False
Me.chkObey.Value = False
End Sub

Private Sub cmdSave_Click()
With m_oEmployeeInfo
.Name = txtName.Text
.School = txtSchool.Text
.Ability = chkAbility.Value
.Obey = chkObey.Value
End With
If Not m_oEmployeeInfo.ValidateData Then
MsgBox "姓名和畢業(yè)院校必填", vbOKOnly, "不能保存"
Exit Sub
Else
m_blnSaved = m_oEmployeeInfo.Save
End If
DoAfterSave m_blnSaved
End Sub

Private Sub DoAfterSave(success As Boolean)
If success Then
ClearForm
lblID.Caption = m_oEmployeeInfo.GetNextID
MsgBox "記錄已保存"
Else
MsgBox "沒(méi)有保存記錄"
End If
m_blnSaved = False '重設(shè)標(biāo)志
End Sub

Private Sub cmdNew_Click()
'為新記錄設(shè)置窗體
    Dim iAnswer As Integer
'檢查當(dāng)前記錄是否被保存
    If Not m_blnSaved Then '是否有輸入的文本沒(méi)有被保存
        If (Len(Me.txtName.Value & "") + Len(Me.txtSchool.Value & "")) <> 0 Then
iAnswer = MsgBox("有沒(méi)有保存的數(shù)據(jù),想繼續(xù)嗎?", vbYesNo, "沒(méi)有保存數(shù)據(jù)")
If iAnswer = vbYes Then
ClearForm
End If
Else
ClearForm
End If
End If
End Sub

Private Sub cmdCancel_Click()
ClearForm
Unload UserForm1
End Sub