技術指標作為一種參考工具,，在不同的人的眼里會有不同的研判結果,，投資者不應該單以一項指標的訊號而對行情作出絕對的判斷,，因為指標所起的只是一種輔助的作用而不是絕對的作用,。如果采用多種指標可以增加訊號的客觀性與準確性,，也可以增加相對的可信度,。事實上，各項指標之間往往會產(chǎn)生矛盾,，如果多種指標同時皆發(fā)出買賣信號的話,，將極大地提高研判準確性的概率，而三線合一——三金叉見底就是其中最實用的一例,。

　　所謂三金叉見底,，簡而言之就是均線、均量線與ＭＡＣＤ的黃金交叉點同時出現(xiàn),，股價在長期下跌后開始企穩(wěn)筑底,，而后股價緩慢上升，這時往往會出現(xiàn)５日與１０日均線,、５日與１０日均量線以及ＭＡＣＤ的黃金交叉點,，這往往是股價見底回升的重要信號。

　　三金叉見底的市場意義為：股價在長期下跌后人氣渙散,，當?shù)鵁o可跌時開始進入底部震蕩,，隨著主力的逐漸建倉，股價終于開始回升,。剛開始的股價上漲可能是極其緩慢的,，也有可能會潛龍出水、厚積薄發(fā),，但不管怎樣最終都會造成股價底部的抬高與上攻行情的雄起,。當成交量繼續(xù)放大推動股價上行時，５日,、１０日均線,、５日、１０日均量線以及ＭＡＣＤ自然而然地發(fā)生黃金交叉,，這是強烈的底部信號,。隨著股價的推高，底部買入的投資者開始有盈利,，而這種強烈的賺錢示范效應將會吸引更多的場外資金介入,，從而全面爆發(fā)一輪氣勢磅礴的多頭行情。

　　三金叉的出現(xiàn)從技術角度來看有三層含義：１,、短中期均線的金叉表明市場的平均持倉成本已朝有利于多頭的方向發(fā)展,，隨著多頭賺錢效應的不斷擴大，將吸引更多的場外資金入市,；２,、短中期均量線的金叉表明了市場人氣得以進一步的恢復，場外新增資金在不斷地進場,，從而使量價配合越來越理想,；３、ＭＡＣＤ的黃金交叉,，不管是ＤＩＦ,、ＭＡＣＤ是在０軸之上還是在０軸之下，當ＤＩＦ向上突破ＭＡＣＤ時皆為短中期的較佳買點,，只不過前者為較好的中期買點,，而后者僅為空頭暫時回補的反彈?？偠灾?，隨著三金叉的出現(xiàn)，在技術分析“價,、量,、時、空”四大要素中有三個發(fā)出買入信號,，將極大地提高研判準確性的概率,，因此三線合一的三金叉為強烈的見底買入信號。

　　第一個買點為三金叉發(fā)生時,。所謂的５日,、１０日均線、均量線以及ＭＡＣＤ三金叉并非絕對要求同時或同一天金叉的,，這僅是一種簡單的描述,。事實上均線、均量線及ＭＡＣＤ三金叉只要在幾個交易日之內(nèi)發(fā)生,，都可視同于“三金叉”,，由于探底之前往往有一個放量的過程，均量線的金叉往往是第一個出現(xiàn),，三者當中最后一項發(fā)生金叉時就是短中線的買入信號,。

　　第二個買點為三金叉發(fā)生后上攻途中出現(xiàn)回檔時。三金叉見底發(fā)生時,，投資者當時有可能沒有注意到這種極好的短線介入點,，其實在錯過三金叉見底發(fā)生的買入信號之后，投資者仍可等待股價回檔時出現(xiàn)的第二個買機,，最有效的方法是股價在回檔時可在１０日或２０日均線附近可逢低吸納,。只要股價仍保持原始上升趨勢，這種逢低吸納不失為較好的介入時機,。

出水芙蓉+多方疊疊炮+倒掛老鴨頭+斷頭鍘刀

條件選股公式——短線是銀之三金叉見底

nday := 5;
down := close/llv(low,60)<=1.2;
pma1 := ma(close,5);
pma2 := ma(close,10);
vma1 := ma(vol,5);
vma2 := ma(vol,10);
diff := ema(close,12) - ema(close,26);
dea := ema(diff,9);
ppday := barslast(cross(pma1,pma2));
vvday := barslast(cross(vma1,vma2));
macdday := barslast(cross(diff,dea));
sjcjd:= if((ppday<=nday and vvday<=nday and macdday<=nday),1,0);
sjcjd

條件選股公式：D!CSFR (出水芙蓉) 缺省周期：日線

MA1:=MA(CLOSE,20);
MA2:=MA(CLOSE,40);
MA3:=MA(CLOSE,60);
{A1:=(OPEN<MA1 AND OPEN<MA2) OR (OPEN<MA2 AND OPEN<MA3) OR (OPEN<MA1 AND OPEN<MA3);}
A1:=OPEN<MA1 OR OPEN<MA2 OR OPEN<MA3;
A2:=C>MAX(MA1,MAX(MA2,MA3));
A3:=V/MA(V,30)>1.2;
A4:=C/REF(C,1)>1.049;
TJ:=A1 AND A2 AND A3 AND A4;
TJ;

出水芙蓉：
股價長期在季均線之下滑跌,，某日突然放量沖過季均線并收在季均線之上,，這一根陽線稱為出水芙蓉。
操作：
在出現(xiàn)出水芙蓉圖形當日買入或之后逢低買入,。

條件選股公式：D!DFDDP (多方疊疊炮) 缺省周期：日線

A1:=REF(CLOSE,2)>REF(OPEN,2) AND REF(CLOSE,1)<REF(OPEN,1) AND CLOSE>OPEN;
TJ:=A1 AND REF(BARSLAST(A1),1)<9 AND C/REF(C,10)>1.1;

多方疊疊炮（兩陽夾一陰）：
陽-陰-陽的K線組合,，在一定周期內(nèi)出現(xiàn)兩次，且后者是在上升一定空間后出現(xiàn),。

條件選股公式：D!DFH (東方紅大陽升) 缺省周期：日線

HSL:=V/CAPITAL*100;
YB:=HSL>4 AND C>REF(C,1);
A1:=COUNT(YB,13)>=3;
A2:=C/REF(C,1)>1.049 AND HSL>5;
A3:=REF(SUMBARS(V,CAPITAL),13)>89;
A4:=HIGH/C<1.021;
A5:=COUNT(C/REF(C,1)>1.04,10)<5;
A6:=IF(COUNT(HSL>4,5)>=3,0,1);
ZTJ:=A1 AND A2 AND A3 AND A4 {AND A5 AND A6};
ZTJ AND (REF(BARSLAST(ZTJ),1)>20 OR BARSSINCE( ZTJ)=0);

東方紅大陽升：
當股價底部形成時,，日K線圖上會出現(xiàn)多根放量陽線，然后大陽突破,，這就是東方紅大陽升,。
97、98,、99三年勝率64.67%（302：165）
操作：
在出現(xiàn)東方紅大陽升后逢低買入,。

條件選股公式：D!DFP (多方炮) 缺省周期：日線

A1:=REF(CLOSE,2)>REF(OPEN,2) AND REF(CLOSE,1)<REF(OPEN,1) AND CLOSE>OPEN;

多方炮（兩陽夾一陰）：
陽-陰-陽的K線組合。

條件選股公式：D!DGLYT (倒掛老鴨頭) 缺省周期：日線

MA5 := MA(close,5);
MA10 := MA(close,10);
MA60 := MA(close,60);
pday1 := barslast(cross(ma60,ma5));{5日均線下穿60日均線}
pday2 := barslast(cross(ma60,ma10));{10日均線下穿60日均線,，至此形成鴨頸部}
pday3 := barslast(low=llv(low,pday2));{形成頭部,，要反彈}
pday4 := barslast(cross(ma5,ma10));{反彈后，5日均線和10日均線金叉}
pday5 := barslast(cross(ma10,ma5));{反彈不久,，5日均線和10日均線形成死叉,，形成嘴部}
a1:= pday1>pday2 and pday2>pday3 and pday3>pday4 and pday4>pday5 and pday5<5;
a2:= count(cross(ma10,ma5),pday2)=1;
A1 AND A2;

倒掛老鴨頭：
（1）采用5、10和60周期的價格平均線,。當5日,、10日均線跌破60日平均線后，形成鴨頸部,。
（2）股價反彈時形成的低點形成鴨頭部,。
（3）當股價反彈不久，5日,、10日均線再次死叉向下形成鴨嘴部,。
操作：
（1）在5日、10日均線放量跌破60日平均線形成鴨頸部時賣出,。
（2）在鴨嘴部附近5日,、10日均線死亡交叉時賣出。
（3）當股價放量跌破鴨頭頂瞬間時賣出,。

條件選股公式：D!DIFSCLX (DIF上穿零線) 缺省周期：日線

dif:=ema(close,12)-ema(close,26);
count(dif>=0,60)=1 and dif>=0;

DIF上穿零線：
（1）當股價長期下跌后,，DIF始終運行在零線以下，呈現(xiàn)負數(shù),。
（2）當股價底部抬高后或股價沖過季均線后,，會出現(xiàn)DIF上穿零線，呈現(xiàn)正數(shù)。
（3）有時股價并未啟動,，但DIF會率先上穿零線,，對未來的漲勢有預報作用。
操作：
（1）在DIF上穿零線時買入股票,。
（2）在DIF上穿零線后等待三金叉見底時逢低買入,。

條件選股公式：D!DIFXCLX (DIF下穿零線) 缺省周期：日線

dif:=ema(close,12)-ema(close,26);
count(dif<=0,60)=1 and dif<=0;

DIF上穿零線：
（1）當股價長期上漲后,，DIF始終運行在零線以上,，呈現(xiàn)正數(shù)。
（2）當股價難創(chuàng)新高或股價跌破季均線時,，會出現(xiàn)DIF下穿零線,，呈現(xiàn)負數(shù)。
（3）有時股價跌勢還未展開,，但DIF會率先下穿零線,，對未來的跌勢有預報作用。
操作：
（1）在DIF下穿零線時賣出股票,。
（2）在DIF下穿零線后等待三死叉見頂時逢高賣出,。

條件選股公式：D!DTZD (斷頭鍘刀) 缺省周期：日線

MA1:=MA(CLOSE,20);
MA2:=MA(CLOSE,40);
MA3:=MA(CLOSE,60);

A1:=OPEN>MA1 OR OPEN>MA2 OR OPEN>MA3;
A2:=C<MIN(MA1,MIN(MA2,MA3));
A3:=COUNT(C>MIN(MA1,MIN(MA2,MA3)),34)>30;
A4:=C/REF(C,1)<0.97;

TJ:=A1 AND A2 AND A3 AND A4;

斷頭鍘刀：
股價長期在季均線之上爬升，某日突然放量跌破季均線并收在季均線之下,，這一根陰線稱為斷頭鍘刀,。
操作：
在出現(xiàn)斷頭鍘刀圖形當日賣出或之后逢高派發(fā)。
注意：本公式用于空頭選股,。

條件選股公式：D!FLGT (放量過頭) 缺省周期：日線

highprice := hhv(high,60); {60日內(nèi)最高價}

A1:= Close>highprice;{股價在沖擊前高位}

A2:= (vol>ma(vol,5)*2.5) or (COUNT(Vol>ma(vol,10),6)>4);{近期明顯放量}

A1 AND A2;

放量過頭：
（1）股價在沖過前一個頭部時放出巨大的成交量,。
（2）有時是單根的巨大陽線，有時是溫和放量的幾根陽線,，總之在沖過前頭部時有成交量的配合,。
操作：
（1）當出現(xiàn)巨量沖過前頭部時，一般都應及時跟進,。
（2）當出現(xiàn)幾天的溫和放量時,，也應積極介入。
（3）前頭部不會永遠阻礙股價上升,，而股價通過前頭部時只要能放量一般都可買入,。
（4）前頭部是上升浪的底部,。

條件選股公式：D!HMCSF (黑馬草上飛) 缺省周期：日線

LCZ:=(C-MA(C,60))/MA(C,60)*100;

A1:=COUNT(MA(C,60)>REF(MA(C,60),1),100)>95;
A2:=COUNT(LCZ<20,100)>95;
A3:=COUNT(C>MA(C,60),100)>80;
A4:=C/REF(C,1)>1.04;
A5:=V/CAPITAL*100>2.8;

ZTJ:=A1 AND A2 AND A3 AND A4 AND A5;
ZTJ AND (REF(BARSLAST(ZTJ),1)>20 OR BARSSINCE( ZTJ)=0);

黑馬草上飛：
1,、60日價格均線平穩(wěn)上揚。
2,、日K線按照60日均線斜率震蕩上行,。
3、經(jīng)過大半年的震蕩向上，終于向上突破,。
操作：
發(fā)出信號后逢低積極介入,。

條件選股公式：D!JYA (價壓) 缺省周期：日線

參數(shù)描述： N1(1,300,20)N2(1,300,40)N3(1,300,60)

MA1:=MA(CLOSE,N1);
MA2:=MA(CLOSE,N2);
MA3:=MA(CLOSE,N3);
YA:=COUNT(CROSS(MA2,MA1),21)=1 AND CROSS(MA3,MA2) AND
COUNT(CROSS(MA3,MA1),21)=1 AND
BARSLAST(CROSS(MA2,MA1))>BARSLAST(CROSS(MA3,MA1)) AND
BARSLAST(CROSS(MA3,MA1))>BARSLAST(CROSS(MA3,MA2)) AND
MA1<REF(MA1,1);

價壓：
短期、中期,、長期三條均線自上而下扭轉向下所形成的封閉三角形,。常用的有季壓與月壓：
由5、10,、20日均線這個月均線系統(tǒng)組成的壓為“月壓”,；
由20、40,、60日均線這個季均線系統(tǒng)組成的壓為“季壓”,；
操作：
1、在三個死亡交叉點附近逢高賣出,。
2,、看清楚價壓后在反彈時逢高賣出,。
注意：本公式為空頭公式,。

構成價壓的均線日期
短期Param#1日均線;
中期Param#2日均線;
長期Param#3日均線;
一般情況下：月壓取5，10,，20；
季壓取20,，40,，60,；

條件選股公式：D!JZZ (金蜘蛛) 缺省周期：日線

參數(shù)描述： N1(1,300,5)N2(1,300,10)N3(1,300,20)

MA1:=MA(CLOSE,N1);
MA2:=MA(CLOSE,N2);
MA3:=MA(CLOSE,N3);

A1:=COUNT(CROSS(MA2,MA3),2)=1;
A2:=COUNT(CROSS(MA1,MA3),2)=1;
A1 AND A2;

金蜘蛛：
短期、中期,、長期三條均線自上而下,，并且扭轉向上所形成的結點,。
操作：
1,、在金蜘蛛出現(xiàn)后應逢低買入,。
2,、在金蜘蛛圖形下出現(xiàn)量托，更應積極買入,。

構成金蜘蛛的均線日期
短期Param#1日均線;
中期Param#2日均線;
長期Param#3日均線;
一般情況下：金蜘蛛取5,，10,，20日。

條件選股公式：D!KFP (空方炮) 缺省周期：日線

REF(CLOSE,2)<REF(OPEN,2) AND REF(CLOSE,1)>REF(OPEN,1) AND CLOSE<OPEN;

空方炮（兩陰夾一陽）：
陰-陽-陰的K線組合,。

條件選股公式：D!LBCJ (獵豹出擊) 缺省周期：日線

M1:=MA(C,60);

A1:=COUNT(C<M1,33)>31;
A2:=CROSS(C,M1);
A3:=C/REF(C,1)>1.045;

A1 AND A2 AND A3;

獵豹出擊：
股價長期在60日均線之下滑跌,，某日突然拉大陽沖過60日線并收在60日均線之上，在日線中這一根陽線稱為獵豹

出擊,。
操作：
在出現(xiàn)獵豹出擊圖形當日買入或之后逢低買入,。

條件選股公式：D!LDTLD (量頂天立地) 缺省周期：日線

A1:=V=HHV(V,120);
A2:=C/OPEN>1.049;
TJ:=A1 AND A2;
TJ AND (REF(BARSLAST(TJ),1)>80 OR BARSSINCE(TJ)=0);

量頂天立地：
某日出現(xiàn)半年來的天量，且收出大陽線,。
本公式集有一個量頂天立地五彩K線公式D!LDTLDWC與本公式對應。

條件選股公式：D!LYT (老鴨頭) 缺省周期：日線

MA5 := MA(close,5);
MA10 := MA(close,10);
MA60 := MA(close,60);

pday1 := barslast(cross(ma5,ma60));{5日均線上穿60日均線}
pday2 := barslast(cross(ma10,ma60));{10日均線上穿60日均線,，至此形成鴨頸部}
pday3 := barslast(high=hhv(high,pday2));{形成頭部,，要下跌}
pday4 := barslast(cross(ma10,ma5));{下跌后,，5日均線和10日均線死叉}
pday5 := barslast(cross(ma5,ma10));{回落不久,，5日均線和10日均線形成金叉，形成嘴部}

a1:= pday1>pday2 and pday2>pday3 and pday3>pday4 and pday4>pday5 and pday5<5;

a2:= count(cross(ma10,ma5),pday2)=1;

A1 AND A2;

老鴨頭：
（1）采用5,、10和60周期的價格平均線,。當5日、10日均線放量上穿60日平均線后,，形成鴨頸部,。
（2）股價回落時形成的高點形成鴨頭部。
（3）當股價回落不久,，5日,、10日均線再次金叉向上形成鴨嘴部。
操作：
（1）在5日,、10日均線放量上穿60日平均線形成鴨頸部時買入,。
（2）在鴨嘴部附近成交量芝麻點一帶逢低買入。
（3）當股價放量沖過鴨頭頂瞬間時介入,。

條件選股公式：D!LZMD (量芝麻點) 缺省周期：日線

V1:=MA(V,40);
HSL:=V/CAPITAL*100;

A1:=COUNT(V/V1<1.3,14)>11;
A2:=CROSS(HSL,2);
A3:=C/REF(C,1)>1.025 AND C>OPEN;

ZTJ:=A1 AND A2 AND A3;

量芝麻點：
成交量連續(xù)出現(xiàn)萎縮,，在量柱體圖上表現(xiàn)為小芝麻點，連續(xù)的小芝麻點與40日量平均線形成一個小水坑,。
操作建議：
最好K線淺幅回檔,，且成交量越小越好，當放量上行時買入,。

條件選股公式：D!QLQS (青龍取水) 缺省周期：日線

A1:=MIN(MA(C,5),MA(C,10))>MA(C,60) AND CROSS(MA(C,5),MA(C,10));
A2:=MIN(MA(C,5),MA(C,10))/MA(C,60)<1.05;
A3:=COUNT(V<MA(V,10),10)>6;

A1 AND A2 AND A3;

青龍取水：
1,、在5日、10日,、60日均線圖上,，5、10日均線起伏不定，日K線在60日均線上逶迤,。
2,、龍頭回到60日均線附近，猶如青龍取水,，同時成交量萎縮
3,、然后大漲。
操作：待龍頭形成,，成交量萎縮又放大后,，逢低介入。

條件選股公式：D!QSGT (輕松過頭) 缺省周期：日線

nday := hhvbars(high,120); {120日內(nèi)最高價的周期數(shù)}
nday1:= nday-10; {最高點之后10日}
nday2:= nday+10; {莊家應該在nday1--nday2之間吸納大部分籌碼}

a1 := nday>=30;{確保高點出現(xiàn)的周期數(shù)大于30}

a2 := ref(sum(vol,20),nday1) > finance(7) * 0.4; {吸納40%}

VMA:=MA(Vol,40);{40日量均線}

A3:=COUNT(Vol<VMA,nday1)/nday1>0.9;{成交量呈現(xiàn)芝麻點}

A4:=Close>=hhv(high,120);{股價在沖擊前高位}

A5:=COUNT(Vol<(MA(vol,10)*1.3),10)>8;{近期無明顯放量}

A1 AND A2 AND A3 AND A4 AND A5;

輕松過頭：
（1）前一個頭部下方的成交量巨大,，股價筑頭后開始回檔,。
（2）回檔完畢后成交量呈量芝麻點，股價再次上揚沖擊前一頭部,。
（3）輕松沖過前一頭部并未明顯放量,。
操作：
（1）在前一頭部成交量巨大時跟進。
（2）在回檔完畢后成交量呈現(xiàn)芝麻點時逢低吸納,。
（3）最經(jīng)濟,、最大利潤化的方法是在輕松過頭前的一瞬間迅速介入。
（4）前頭部價格一般是上升浪的腰部,。

條件選股公式：D!SJCJD (三金叉見底) 缺省周期：日線

nday := 5;

down := close/llv(low,60)<=1.2;

pma1 := ma(close,5);
pma2 := ma(close,10);

vma1 := ma(vol,5);
vma2 := ma(vol,10);

diff := ema(close,12) - ema(close,26);
dea := ema(diff,9);

ppday := barslast(cross(pma1,pma2));
vvday := barslast(cross(vma1,vma2));
macdday := barslast(cross(diff,dea));

sjcjd:= if((ppday<=nday and vvday<=nday and macdday<=nday),1,0);

三金叉見底：
（1）當股價長期下跌后開始企穩(wěn)筑底,，而后股價緩慢上升。有時會同時出現(xiàn)5日和10日均價線,、5日和10日均量

線,、MACD的黃金交叉點，這是股價見底回升的信號,。
（2）有時會伴隨出現(xiàn)兩陽夾一陰多方炮,、出水芙蓉、量頂天立地和MACD上穿零線等圖形,。
操作：
（1）當出現(xiàn)三金叉后開始買入股票,。
（2）或等股價回檔時在10日均線附近逢低吸納。

條件選股公式：D!SSCJD (三死叉見頂) 缺省周期：日線

nday := 5;

down := hhv(high,20)/high<=1.15;

pma1 := ma(close,5);
pma2 := ma(close,10);

vma1 := ma(vol,5);
vma2 := ma(vol,10);

diff := ema(close,12) - ema(close,26);
dea := ema(diff,9);

ppday := barslast(cross(pma2,pma1));
vvday := barslast(cross(vma2,vma1));
macdday := barslast(cross(dea,diff));

sscjd:= if((ppday<=nday and vvday<=nday and macdday<=nday),1,0);

三死叉見頂：
（1）當股價長期上漲后開始進入頭部,，而后股價緩慢下跌,。有時會同時出現(xiàn)5日和10日均價線、5日和10日均量

線,、MACD的死亡交叉點,，這是股價見頂回落的信號。
（2）有時會伴隨出現(xiàn)兩陰夾一陽空方炮,、斷頭鍘刀MACD下穿零線等圖形,。
操作：
（1）當出現(xiàn)三死叉后堅決賣出股票,。
（2）或等股價反彈到10日均線附近逢高派發(fā)。

條件選股公式：D!SZZ (死蜘蛛) 缺省周期：日線

參數(shù)描述： N1(1,300,5)N2(1,300,10)N3(1,300,20)

MA1:=MA(CLOSE,N1);
MA2:=MA(CLOSE,N2);
MA3:=MA(CLOSE,N3);

A1:=COUNT(CROSS(MA3,MA2),2)=1;
A2:=COUNT(CROSS(MA3,MA1),2)=1;

A1 AND A2;

死蜘蛛：
短期,、中期,、長期三條均線自下而上，并且扭轉向下所形成的結點,。
操作：
1,、在死蜘蛛出現(xiàn)后應逢高派發(fā)。
2,、在死蜘蛛圖形下出現(xiàn)量壓,，更應加快派發(fā)。
注意：本公式為空頭選股,。

構成死蜘蛛的均線日期
短期Param#1日均線;
中期Param#2日均線;
長期Param#3日均線;
一般情況下：死蜘蛛取5,，10，20日,。

條件選股公式：D!TSJDXJ (天上井地下井) 缺省周期：日線

M1:=MA(C,5);
M2:=MA(C,10);
M3:=MA(C,20);
M4:=MA(C,30);

TSJ:=COUNT(CROSS(M3,M1),21)=1 AND COUNT(CROSS(M4,M1),21)>0 AND
COUNT(CROSS(M3,M2),21)>0 AND COUNT(CROSS(M4,M2),21)>0;
MM1:=MA(V,5);
MM2:=MA(V,10);
MM3:=MA(V,20);
MM4:=MA(V,30);

DXJ:=COUNT(CROSS(MM3,MM1),21)=1 AND COUNT(CROSS(MM4,MM1),21)>0 AND
COUNT(CROSS(MM3,MM2),21)>0 AND COUNT(CROSS(MM4,MM2),21)>0;

ZTJ:=COUNT(TSJ,13)>0 AND COUNT(DXJ,13)>0;

ZTJ AND (REF(BARSLAST(ZTJ),1)>20 OR BARSSINCE( ZTJ)=0);

天上井地下井：
5日,、10日價格均線跌破20、30日均線形成一個井字這是天上井,，在此前后同樣周期的量均線也形成這樣的井字

,，
是地下井
這是一個空頭選股公式。
操作：
如果出現(xiàn)在高位,，則表示頭部形成，要及時逢高派發(fā),。

條件選股公式：D!TUO (價托) 缺省周期：日線

參數(shù)描述： N1(2,200,20)N2(2,200,40)N3(2,200,60)

MA1:=MA(CLOSE,N1);
MA2:=MA(CLOSE,N2);
MA3:=MA(CLOSE,N3);
TUO:=COUNT(CROSS(MA1,MA2),21)=1 AND CROSS(MA2,MA3) AND
COUNT(CROSS(MA1,MA3),21)=1 AND
BARSLAST(CROSS(MA1,MA2))>BARSLAST(CROSS(MA1,MA3)) AND
BARSLAST(CROSS(MA1,MA3))>BARSLAST(CROSS(MA2,MA3)) AND
MA1>REF(MA1,1);

價托：
短期,、中期、長期三條均線自下而上扭轉向上所形成的封閉三角形,。常用的有季托與月托：
由5,、10、20日均線這個月均線系統(tǒng)組成的托為“月托”,；
由20,、40、60日均線這個季均線系統(tǒng)組成的托為“季托”,；
操作：
1,、在三個黃金交叉點附近分批逢低買入。
2,、看清楚價托后在回檔時逢低買入,。

 
構成價托的均線日期
短期Param#1日均線;
中期Param#2日均線;
長期Param#3日均線;
一般情況下：月托取5，10,，20,；
季托取20,，40，60,；